검색결과 리스트
jni에 해당되는 글 1건
- 2008.07.10 [Java]어셈블리 언어 프로그램에서 자바 애플리케이션 실행
글
자바 네이티브 인터페이스(JNI)는 기본 언어 프로그램과 자바 가상 시스템(JVM) 사이의 통신 설정에 사용할 수 있는 메커니즘입니다. JVM과 C/C++ 코드 간의 상호 작용에 대해서는 JNI 관련 설명서나 JNI에 관한 기술 문서에서 자세히 다룹니다. 또 자바 SDK는 자바 코드를 사용한 C/C++ 프로그램 호출을 용이하게 하는 헤더 파일 생성 유틸리티도 제공합니다.
그러나 자바와 어셈블리 언어 코드의 연동에 대해 다룬 문서는 찾아보기가 어렵습니다. 저는 이전 기사를 통해 자바 애플리케이션에서 어셈블리 언어 프로그램을 호출하는 방법을 설명한 바 있습니다. 이번에는 어셈블리 언어 코드로 자바 메소드를 호출하는 데모 애플리케이션을 통해 ASM 프로세스에서 자바 프로그램을 호출하는 방법에 대해 소개하겠습니다. 이 자바 메소드는 Swing JDialog를 띄워서 실제로 실행되었음을 보여 줍니다.
ASM 기능의 자바를 선택하는 이유
자바를 구현하려면 JNI가 꼭 필요합니다. JVM의 일부 기능은 기본 플랫폼과의 상호 작용을 통해서만 구현되기 때문입니다. 그러나 이것 말고도 자바 클래스는 흔히 다른 언어로 작성된 애플리케이션을 보완하는 데 유용합니다. 자바는 고급 기능을 아주 간단하게 구현할 수 있도록 하는 광범위한 API를 제공하기 때문입니다.
얼마 전에 저는 몇 가지 소스에서 실시간 데이터를 수집하고 수집된 데이터를 순환 버퍼에 저장하여 버퍼가 가득 차면 새 데이터로 예전 데이터를 덮어쓰게 하는 애플리케이션 작업에 참여한 적이 있습니다. 지정된 트리거 이벤트가 디지털 입력에서 감지되면 정해진 수의 데이터 샘플을 버퍼에 저장하여 트리거 이전과 이후의 데이터 스냅샷을 볼 수 있도록 했습니다. 이때 원본 애플리케이션은 어셈블리 언어로 작성했습니다.
이 애플리케이션을 몇 달 사용해 본 결과, 트리거 이벤트가 발생할 때마다 애플리케이션이 권한 있는 감독자에게 스냅샷을 메일로 보내도록 하면 정말 편리하겠다는 생각이 들었습니다. 물론 그런 확장 기능을 어셈블리로 작성할 수도 있었지만, 팀원들은 이런 경우에는 자바로 확장 기능을 만든 다음, ASM 프로그램으로 기능을 연결하는 것이 더 쉽다는 의견이었습니다. 저는 ASM 지향의 JNI로 작업해 본 경험이 있었기 때문에 그것이 가능하다는 것을 알았고, 실제로 그 프로젝트는 금새 구현되어 성공을 거두었습니다.
이러한 애드온을 활용할 수 있는 어셈블리로 작성된 레거시 애플리케이션이 많은 것으로 알고 있습니다. 그러나 JNI를 유용하게 쓸 수 있는 것은 레거시 애플리케이션의 개조만이 아닙니다. 믿지 않는 분들도 많으시겠지만, 아직도 신규 프로그램의 특정 부분을 어셈블리 언어로 작성하는 경우가 있습니다.
얼마 전 발표된 어떤 기사에서 저자는 "핫 코드 경로를 최대한 효율적으로 만들기 위해 아직도 제품에 어셈블리 언어를 사용하는 썬 파트너들이 많다는 사실을 발견했다. 최신 컴파일러는 종전보다 훨씬 효율적인 코드를 만들어내지만, 컴파일러로 작성한 코드는 각각의 마이크로프로세서 명령에서 최대한 성능을 짜내는 방법을 알고 있는 엔지니어가 수작업으로 작성한 어셈블리에 비해 성능이 떨어진다. 프로그래머의 재량이 발휘될 여지가 많은 어셈블리 언어는 여전히 강력한 최적화 도구로 남아 있으며 현명하게 사용하면 성능을 높일 수 있다"고 주장했습니다. 이러한 "혼합 언어" 애플리케이션에서 ASM 기능의 자바를 사용할 수 있다는 것은 분명히 이익이 됩니다.
여기서 제시하는 방법은 ASM이 아닌 언어의 자바 코드를 호출할 때도 사용할 수 있습니다. JInvoke를 .dll로 다시 작성하는 경우, 예를 들어 FORTRAN 언어로 작성한 코드를 여기에 링크하여 자바 메소드를 호출할 수 있습니다.
저는 레거시 ASM 코드의 JNI를 다음 두 가지에 사용했습니다.
- 기능 향상: 앞서 언급했듯이 기존 ASM 애플리케이션에 메일링 기능을 추가했습니다.
- 인터페이스 향상: 쌍방향 사용자 인터페이스를 추가했습니다(대부분 AWT이지만 일부 Swing도 포함).
이렇게 향상된 애플리케이션을 Windows 2000 및 XP에서 실행해 보았습니다. 사용한 자바 버전은 1.3, 1.4, 1.6입니다. 그 결과, 모든 애플리케이션이 원활하게 작동되었습니다.
권장 다운로드
제가 데모 코드에 사용한 어셈블리 언어의 버전은 MASM32입니다. 전체 MASM32 번들을 무료로 다운로드할 수 있으며, 자바-ASM의 상호 작용을 시험하려면 이 번들을 컴퓨터에 설치해야 합니다. Iczelion의 사이트에는 MASM 프로그래밍에 대한 매우 유용한 튜토리얼 세트가 있습니다. JNI에 관한 문서 중 최고는 Sheng Liang의 책 The Java Native Interface: Programmer's Guide and Specification입니다.
이 책도 무료로 다운로드할 수 있습니다. 이 기사에 수록된 자바 코드 샘플(AsmToJava)을 실행하려면 SDK(최소한 JRE)가 필요합니다. 데모에서 어셈블리 언어를 사용한 JInvoke 부분은 .exe 파일로 컴파일했으며 MASM 번들 없이도 실행됩니다. 소스 코드를 수정하여 다시 컴파일하려는 경우에만 어셈블러/링커가 필요합니다.
기본 원리
JNI는 종합적인 JVM 인터페이스입니다. 이 인터페이스는 주로 풍부한 함수로 알아볼 수 있습니다. 기본 코드는 이러한 함수를 호출하여 구현된 JVM과 상호 작용합니다. 자세한 함수 설명은 Sheng Liang의 책을 참조하십시오. 이러한 함수는 대부분 JVM을 만들어야만 액세스가 가능하지만 JNI에서 몇 가지 기본 함수를 직접 내보낼 수도 있습니다. 나중에 자세히 다루겠지만, 두 번째 유형의 함수로 JVM을 인스턴스화하여 다른 JNI 함수를 호출할 수도 있습니다.
일단 JVM이 작성되면 JVM 인스턴스가 있어야만 구현 가능한 JNI 함수에 어셈블리 언어 프로그램이 액세스할 수 있게 됩니다. 이러한 모든 JNI 함수에 대한 포인터는 함수 테이블이라는 테이블에 저장됩니다. JVM을 로드하는 ASM 코드는 사실상 포인터인 JNIEnv라는 변수를 수신합니다. 그리고 JNIEnv는 함수 테이블에 대한 실제 포인터가 들어 있는 메모리의 특정 위치를 가리킵니다. 그림 1은 이러한 액세스 체인을 보여 줍니다.
보시다시피 JNI 함수에 대한 각 포인터는 길이가 4바이트입니다. 따라서 함수 테이블의 시작 주소에 해당 함수 색인의 4배를 더하여 정의된 위치에서 원하는 함수의 포인터를 찾을 수 있습니다. 함수 색인은 0을 기준으로 합니다. 즉, 첫 번째 함수의 포인터는 색인 0, 두 번째 함수의 포인터는 색인 1과 같이 이어집니다. Sheng Liang의 책에는 모든 JNI 함수의 색인 값이 나열되어 있습니다.
ASM 코드로 자바 프로그램을 호출하려면 다음 단계를 실행해야 합니다.
- JVM 인스턴스화
- 클래스 찾기
- 메소드 ID 확인
- 메소드 호출
각 단계를 자세히 살펴보기 전에, 이 프로그램 및 유사 프로그램을 손쉽게 작성하기 위해 include 파일을 사용하는 방법부터 알아보겠습니다. 자바와 기본 코드 사이의 상호 작용은 JNI로 노출된 함수를 통해 이루어지므로 기본 프로세스에서 이러한 함수를 반복적으로 호출할 필요가 있습니다. 따라서 이 활동을 처리하기 위해 매크로를 사용하겠습니다. 그러면 길이가 상당히 길고 비슷한 코드를 반복해서 작성할 필요가 적어지며 오타로 인해 프로그램에 버그가 생길 위험도 줄일 수 있습니다.
매크로
ASM 코드에서 함수를 호출할 때는 함수 테이블에서 해당 함수의 포인터를 찾은 뒤 그 포인터를 사용하여 원하는 함수를 호출해야 합니다. 앞서 설명했듯이, 포인터를 찾으려면 JNIEnv 포인터 체인을 따라 함수 테이블의 시작 주소를 확인한 다음, 해당 함수의 색인을 사용하여 함수 포인터를 검색해야 합니다. 함수 테이블의 시작 주소를 확인하는 첫 번째 작업에는 항상 동일한 코드를 사용하며 다음과 같은 매크로로 처리할 수 있습니다.
;This macro returns the pointer to
;Function Table in fnTblPtr
GetFnTblPtr MACRO envPtr, fnTblPtr
mov ebx, envPtr
mov eax, [ebx]
mov fnTblPtr, eax
ENDM
위의 코드로 정의되는 매크로는 매개변수 두 개를 취합니다. 첫 번째는 JNIEnv 포인터이고, 두 번째는 이 매크로가 해당 포인터를 반환하게 될 함수 테이블의 위치를 가리킵니다. 매크로는 함수 테이블 포인터를 eax로 로드한 다음, 이를 fnTblPtr에 저장합니다. 프로그램 자체에 이 매크로를 정의하여 사용할 수도 있습니다. 아니면 여기서 선택한 방법처럼 이러한 매크로를 모두 include 파일에 정의한 다음, include 문을 통해 ASM 프로그램과 함께 이 파일을 사용해도 됩니다. 여기서 사용한 include 파일은 jav_asm.inc입니다. 이 파일은 GetFnTblPtr 매크로뿐 아니라 이 예제에 필요한 다른 매크로도 모두 정의합니다. 또한 jav_asm.inc는 매크로 외에도 JVM을 작성하는 함수의 원형은 물론 해당 함수의 매개변수로 사용할 구조도 정의합니다. 끝으로, java_asm.inc는 사용하기 편리하도록 모든 JNI 함수에 기호 이름을 지정해 줍니다.
함수 테이블에 대한 포인터가 확인되었으면 원하는 함수의 포인터를 검색해야 합니다. 여기 사용되는 코드도 색인 부분을 제외하면 항상 동일합니다. 이 작업은 다음 매크로로 처리합니다.
;This macro returns the pointer
;to a function in fnPtr.
GetFnPtr MACRO fnTblPtr, index, fnPtr
mov eax, index
mov ebx, 4
mul ebx
mov ebx, fnTblPtr
add ebx, eax
mov eax, [ebx]
mov fnPtr, eax
ENDM
이 매크로는 index 값에 4를 곱하고 그 결과를 함수 테이블의 시작 주소(fnTblPtr 참조)에 더하여 액세스할 함수의 포인터를 확인합니다. 그런 다음, 이 포인터를 fnPtr에 저장합니다.
나머지 세 매크로도 처리하는 매개변수의 수만 제외하면 거의 동일합니다.
;The next 3 macros push parameters as per
;stdcall and call the function through fnPtr
CallFunction2 MACRO param1, param2, fnPtr
push param2
push param1
call [fnPtr]
ENDM
CallFunction3 MACRO param1, param2, param3, fnPtr
push param3
push param2
push param1
call [fnPtr]
ENDM
CallFunction4 MACRO param1, param2, param3, param4, fnPtr
push param4
push param3
push param2
push param1
call [fnPtr]
ENDM
보시다시피 이들 매크로는 fnPtr을 제외하고 stdcall을 위해 매개변수를 역순으로 푸시(push)한 다음, fnPtr을 포인터로 사용하여 해당 함수를 호출합니다.
이로써 기본적인 빌딩블록이 완성되었습니다. 이제 데모 애플리케이션의 4단계 시퀀스를 살펴보겠습니다.
JVM 인스턴스 작성
JInvoke는 명령줄에서 자바 애플리케이션을 실행할 때 java 명령이 하는 것과 거의 비슷한 방식으로 JVM 인스턴스를 작성합니다. 구현된 자바 가상 시스템(JVM)은 기본 애플리케이션이 가상 시스템을 로드할 수 있도록 하는 호출 인터페이스라는 메커니즘을 제공합니다. java 명령은 이 호출 인터페이스를 사용하는 C 프로그램을 호출하여 자바 애플리케이션을 실행하고, JInvoke도 바로 이 인터페이스를 사용합니다. JVM을 로드하는 코드는 다음과 같습니다.
.
.
.
va vm_args <>
jvmo JavaVMOption <>
.
.
.
mov jvmo.optionString, offset opzero
mov va.options, offset jvmo
mov va.version, 00010002h
mov va.nOptions,1
mov va.ignoreUnrecognized, TRUE
invoke JNI_CreateJavaVM, offset JavaVM, offset JNIEnv,
offset va
여기서는 우선 구조 두 개를 선언하겠습니다. 이미 설명했듯이 이 구조는 jav_asm.inc에 정의되어 있습니다. JVM을 작성하려면 몇 가지 매개변수를 지정해야 합니다. 지정된 매개변수는 이 구조를 통해 JNI_CreateJavaVM 함수로 전달됩니다.
이 예제에서는 AsmToJava 클래스의 main 메소드를 호출하겠습니다. 제 컴퓨터의 C:\j2sdk1.4.2_05\testjni 폴더에 클래스 파일이 들어 있습니다. JNI 사양에 설명된 방법에 따라 opzero 문자열로 이 경로를 정의합니다. opzero가 jvmo 구조로 로드되고, 그 다음에 jvmo에 대한 오프셋이 va 구조로 로드됩니다. JNI_CreateJavaVM 함수로 전달되는 마지막 매개변수는 va입니다. 따라서 로드된 JVM은 우리가 원하는 클래스를 어디서 찾아야 하는지 알게 됩니다.
JNI_CreateJavaVM은 반환과 동시에 성공한 경우에는 eax에 0을, 실패한 경우에는 eax에 음수값을 반환합니다. 함수로 JVM 인스턴스를 작성하는 데 성공한 경우에는 JVM 인터페이스에 대한 포인터와 해당하는 JNIEnv 포인터를 각각 JavaVM 및 JNIEnv에서 사용할 수 있습니다.
JNI_CreateJavaVM 함수로 반환된 JInvoke는 즉시 eax의 내용을 확인합니다. 값이 0이 아니면 JVM이 로드되지 않은 것입니다. 사용자에게 이를 알리는 메시지가 표시되고 프로세스는 종료됩니다.
.if eax == 0
.
.
.
.else
invoke MessageBox, 0, addr Fail1Text,
addr Caption, 16; failed to create JVM
.endif
한편, eax의 내용이 0이라면 해당하는 메시지를 담은 메시지 상자(그림 2)가 표시되고 다음 단계가 실행됩니다.
.if eax == 0
invoke MessageBox, 0, addr VmText,
addr Caption, 64; indicate success
단, JInvoke는 개념 제시를 위한 수단에 불과하므로 여기서는 가장 간단한 방법으로 JVM 인스턴스를 작성했음을 말씀드립니다. Sheng Liang이 책에서 설명했듯이 이 밖에도 다양한 매개변수를 지정할 수 있습니다.
클래스 찾기
JVM을 로드한 뒤, JInvoke는 원하는 자바 애플리케이션의 시작 지점이 될 클래스를 찾아야 합니다. 아래 코드는 이를 위해 FindClass 함수를 호출합니다.
GetFnTblPtr JNIEnv, fntblptr
GetFnPtr fntblptr, FI_FC, fnptr ; ptr to FindClass
CallFunction2 JNIEnv, offset ProcName,
fnptr ; call FindClass
.if eax != 0
mov classid, eax
invoke MessageBox, 0, addr FcText,
addr Caption, 64; class found
이 클래스 경로는 앞서 jvmo 구조에 로드되었으며(mov jvmo.optionString, offset opzero) 이미 JVM에 알려져 있습니다. FindClass 함수는 클래스를 찾을 수 있는 경우에는 eax에 해당 ID를 반환하고, 그렇지 않으면 0을 반환합니다. 클래스가 발견되면 해당 ID를 저장한 다음, 메시지 상자(그림 3)를 표시하여 사용자에게 알립니다.
클래스를 찾을 수 없는 경우에는 해당하는 메시지와 함께 프로세스가 종료됩니다. 그림 4는 호출한 함수가 성공하지 못했을 때 표시되는 메시지의 예입니다.
메소드 ID 확인
메소드를 호출하려면 해당 ID를 확인해야 합니다. 정적 메소드의 ID를 반환하는 함수는 GetStaticMethodID입니다. 여기서는 AsmToJava 클래스의 main 메소드를 호출하기 위해 이 함수를 사용하겠습니다. 이 함수에는 JNIEnv 외에 다음과 같은 매개변수를 사용할 수 있습니다.
- 해당 메소드가 속한 클래스의 ID. 이전 단계에서 참조한
classid변수입니다. - 메소드 이름.
methodname문자열입니다. - 메소드의 매개변수와 반환 유형을 지정하는 메소드 설명자. 여기서 사용할 메소드의 설명자는
methodsig문자열입니다. 이 경우에 매개변수는String array이고 반환 유형은void입니다. JNI 사양에 관한 Sheng Liang의 책에는 메소드 및 변수의 설명자를 작성하는 방법이 나와 있습니다.
GetStaticMethodID 호출은 지금까지 살펴본 다른 함수 호출과 매우 유사합니다.
GetFnPtr fntblptr, FI_GSMID, fnptr ; ptr to GetStaticMethodID
CallFunction4 JNIEnv, classid, offset methodname,
offset methodsig, fnptr ; GetStaticMethodID
.if eax != NULL
mov methid, eax
invoke MessageBox, 0, addr GsmiText, addr Caption, 64
GetStaticMethodID는 eax에 ID를 반환합니다. 메소드 ID를 확인하는 데 실패한 경우에는 대신 NULL이 반환됩니다. 그리고 JInvoke는 eax의 내용을 확인하여 다음 단계(그림 5)로 진행할지 아니면 프로세스를 종료할지를 결정합니다.
대상 메소드 호출
반환 유형 void로 정적 메소드(여기서는 main 메소드 호출)를 호출하는 JNI 함수는 CallStaticVoidMethod입니다. 다음은 이 함수의 포인터를 확인한 후 필요한 매개변수로 호출하는 코드입니다.
GetFnPtr fntblptr, FI_CSVM, fnptr ; get CallStVM ptr
CallFunction3 JNIEnv, classid, methid, fnptr; call CallStVM
자바 애플리케이션이 성공적으로 실행되었음을 알리는 대화 상자가 나타납니다.
호출한 자바 메소드가 반환되면 JInvoke는 종료됩니다.
ExitProcess 함수를 호출하면 해당 프로세스의 모든 스레드가 정지되며 해당 프로세스에서 작성된 자바 스레드도 정지됩니다. 그러므로 이 방식으로 자바 프로그램을 실행할 때는 필요한 활동이 모두 완료된 뒤에 호출한 자바 메소드가 반환되도록 하는 것이 중요합니다. 실제로 호출 프로세스의 종료 및 JVM에 관한 문제에는 세심한 주의를 기울여야 합니다. 자세한 내용은 Windows API 설명서와 최신 JNI 사양을 참조하십시오.
결론
여기서는 어셈블리 언어 코드로 자바 애플리케이션을 실행하는 데 사용할 수 있는 기본적인 방법을 소개했습니다. 자바 환경에서 안전하게 작업하려면 기본 프로그램에 적절한 오류 확인 기능을 통합해야 합니다. Sheng Liang은 기본 코드의 예외 처리를 비롯하여 다양한 확인 예제를 다루고 있습니다. JNI와 연동되는 ASM 프로그램에는 가급적 이러한 오류 확인 메소드를 사용해야 합니다.
jav_asm.inc 파일을 사용하면 JNI 함수 색인을 손쉽게 지정할 수 있습니다. 번호 대신 기호 이름을 사용하여 색인을 지정하면 오류가 발생할 가능성이 적어집니다. 매크로를 사용하는 것도 오류 감소에 도움이 됩니다. 여러분의 코드에 자유롭게 이 파일을 사용하시고, 필요에 따라 수정하셔도 좋습니다. 그러나 면책 조항 없이 이 파일을 재배포하는 일은 없도록 주의해 주십시오.
JInvoke를 실행할 때 jvm.dll을 찾을 수 없다는 오류 메시지가 나타날 수 있습니다. 이 경우에는 jvm.dll이 포함된 디렉토리 경로를 PATH 환경 변수에 추가해야 할 수 있습니다. 이 DLL은 대개 자바 SDK 루트 폴더의 jre\bin\client 디렉토리에 들어 있습니다. 예를 들어, 제 컴퓨터에서 자바 1.4 릴리스의 해당 경로는 C:\j2sdk1.4.2_05\jre\bin\client입니다. 그러나 자바 1.3을 사용한다면 jre\bin\classic 폴더를 추가해야 합니다. 올바른 경로를 선택하도록 주의하십시오.
끝으로, JInvoke의 include 문에 명명된 파일 경로는 사용자 컴퓨터의 디렉토리 구조에 따라 결정된다는 점을 지적하고 싶습니다. JInvoke에 지정되어 있는 경로는 내 컴퓨터에 해당되는 경로입니다. JInvoke.exe의 경우에는 사용자 시스템에 MASM 구성요소(특히 .inc 또는 .lib 파일)가 로드되지 않아도 실행이 가능합니다. 코드를 수정하여 재컴파일하고 싶으면 해당 디렉토리를 설정한 방식에 맞게 경로 정보를 수정해야 합니다. 그리고 AsmToJava 클래스 파일을 opzero에 정의된 디렉토리에 로드해야 합니다. 아니면 이 클래스의 경로를 적용하여 opzero를 변경해도 됩니다. 그 경우에는 JInvoke의 소스 파일을 재컴파일해야 합니다. 이때 다른 경로 이름도 위의 설명과 같이 수정해야 한다는 점을 잊지 마십시오.
참고 자료
- src.zip: JInvoke 및 AsmToJava의 소스 코드 JInvoke.exe, AsmToJava 클래스 파일과 jav_asm.inc 파일.
- "자바 애플리케이션에서 어셈블리 언어 프로그램 호출." 이 기사에는 보충 정보와 유용한 추가 설명이 수록되어 있습니다.
- The Java Native Interface Programmer's Guide and Specification(자바 네이티브 인터페이스 프로그래머 안내서 및 사양), 저자 Sheng Liang.
- Iczelion의 홈 페이지
Biswajit Sarkar는 프로그램 방식의 산업 자동화를 전문으로 하는 전기공학 엔지니어입니다.
이 글의 영문 원본은
Launch Java Applications from Assembly Language Programs
에서 보실 수 있습니다.
출처 : http://sdnkorea.com
RECENT COMMENT